home *** CD-ROM | disk | FTP | other *** search
/ Languguage OS 2 / Languguage OS II Version 10-94 (Knowledge Media)(1994).ISO / language / embedded / mcu11 / basic11.arc / NOTES155.TXT < prev    next >
Text File  |  1990-10-10  |  25KB  |  473 lines
  1. Release Notes For BASIC11 Version 1.55
  2.  
  3.  
  4. From the programmers viewpoint, version 1.55 of BASIC11 has changed 
  5. very little. Three new commands were added that will be described later in 
  6. this document. The majority of the changes made to BASIC11 allow it be 
  7. easily used in a hardware environment other than Motorola's 
  8. M68HC11EVB. To 'Customize' BASIC11 for a particular hardware 
  9. environment, two areas of the interpreter need to be modified.
  10.  
  11. I/O Routines:
  12.  
  13. In addition to the I/O vector table that is located at $FFA0, all of the I/O 
  14. routines required by BASIC11 to run in an HC11 EVB, were moved to the 
  15. end of the interpreter. The routines begin at address $FF00 and end at 
  16. $FF93 (see listing).
  17.  
  18. BASIC11 performs all of its I/O through the routines INBYTE and 
  19. OUTBYTE. INBYTE expects a single character to be returned in the A-
  20. accumulator. The OUTBYTE routine is entered with a single character 
  21. contained in the A-accumulator. DO NOT CHANGE OR MOVE THE 
  22. INBYTE AND OUTBYTE ROUTINES!!!
  23.  
  24. The routines that perform the actual I/O functions by communicating with 
  25. the hardware in a system are called by INBYTE and OUTBYTE through the 
  26. I/O vector table. The I/O vector table consists of 16 entries. The first eight 
  27. entries may be used for input type devices (INPUT #0...INPUT#7). The 
  28. last eight may be used for output type devices (PRINT #0... PRINT #7). 
  29. Device #0 (both input and output) is reserved for use as the system console 
  30. and should not be used for other purposes. However, this does not mean 
  31. that the system console must consist of a terminal. It could easily consist of 
  32. an LCD display and membrane keyboard.
  33.  
  34. As shown in the listing, each entry in the I/O vector table consists of a two 
  35. byte address. These addresses point to the routines that communicate with 
  36. the actual hardware to perform I/O functions on a character by character 
  37. basis. Studying the listing should serve as a guide in writing a 'device 
  38. driver' for any type of I/O hardware.
  39.  
  40. Environment Variables:
  41.  
  42. The environment variable table, located at $FFC0, consists of eight entries. 
  43. These allow BASIC11 to determine a number of characteristics about the 
  44. hardware environment it is operating in. Each entry is discussed below 
  45. describing its use or function.
  46.  
  47.  7137 FFC0                        org    $ffc0
  48.  7138 FFC0 C000         RAMStart  fdb    $c000        starting address of system RAM.
  49.  7139 FFC2 2000         RAMSize   fdb    $2000        size of BASIC11 RAM Buffer.
  50.  7140 FFC4 6000         EEStart   fdb    $6000        starting address of program storage EEPROM 
  51.  7141 FFC6 2000         EESize    fdb    $2000        size of the program storage EEPROM
  52.  7142 FFC8 1000         IOBase    fdb    $1000        Base Address of the I/O Registers
  53.  7143 FFCA F424         TimeVal   fdb    62500        value used for generating 'Time' Interrupt
  54.  7144 FFCC FF25         UserInit  fdb    IODevInit    Used to initialize console/other hardware.
  55.  7145 FFCE 4000         DFLOPADR  fdb    $4000        Address of flip-flop used to connect the
  56.  7146                                                 HC11 SCI to the host port connector.
  57.  
  58.  
  59. RAMStart
  60.  
  61. The RAMStart entry consists of a two byte address that must point to an 
  62. area of RAM that BASIC11 may use to store its program and/or variables. 
  63. This RAM may be located anywhere in the memory map above $0100. ALL 
  64. PAGE 0 ADDRESSES ($00 - $FF) ARE RESERVED FOR USE BY 
  65. BASIC11!!!
  66.  
  67. RAMSize
  68.  
  69. The RAMSize entry consists of a 16-bit unsigned integer that tells BASIC11 
  70. how much RAM is available for its program and/or variables. A minimum 
  71. suggested size for the RAM is approximately 8K bytes.
  72.  
  73. EEStart
  74.  
  75. The EEStart entry consists of a two byte address that must point to an area 
  76. of memory that BASIC11 may use to store its program and variables when 
  77. an ESAVE command is executed. This area of memory may consist of 
  78. EEPROM, as detailed in the BASIC11 manual, or even battery backed 
  79. RAM.
  80.  
  81. EESize
  82.  
  83. The EESize entry consists of a 16-bit unsigned integer that tells BASIC11 
  84. how much non-volatile memory is available for its program and/or 
  85. variables. The volatile memory should be approximately the same size as 
  86. BASIC11's RAM during program development.
  87.  
  88. IOBase
  89.  
  90. When an MC68HC11 comes out of reset, all of the I/O and control registers 
  91. for it's on chip peripherals are placed in the memory map starting at address 
  92. $1000. Since this address may interfere with other resources in a system, 
  93. the I/O and control registers may be relocated to any 4K boundary within 
  94. the memory map.
  95.  
  96. TimeVal
  97.  
  98. BASIC11 maintains an internal 'clock' that is incremented at a rate that is 
  99. determined partially by the 16-bit unsigned number stored in these two 
  100. bytes. A value of 62500 ($F424) will cause the 'clock' to be incremented 
  101. once per second if the MC68HC11 is running at a 2.0 MHz E-clock (8.0 
  102. MHz crystal) rate.
  103.  
  104. NOTE: When using the 'clock' in conjunction with BASIC11's ONTIME 
  105. function, making the number too small may cause BASIC11 to spend most 
  106. of its time servicing the ONTIME interrupt routine and not executing the 
  107. main portion of the BASIC program. If an ONTIME interrupt routine 
  108. requires a long time to execute, making the number too small may cause 
  109. BASIC11 to become 'stuck' in the interrupt routine.
  110.  
  111. UserInit
  112.  
  113. The UserInit entry consists of a two byte address that points to a subroutine 
  114. used to initialize any hardware or devices in the system. The subroutine is 
  115. called after all of BASIC11's internal initialization is finished. As a 
  116. minimum, the subroutine should initialize any hardware associated with the 
  117. console I/O devices. The subroutine need not preserve any of the HC11's 
  118. registers except the stack pointer.
  119.  
  120. DFLOPADR
  121.  
  122. If BASIC11 is being used with an MC68HC11EVB Rev 'B' or later this 
  123. entry should be left at address $4000. It allows the HC11's SCI port to be 
  124. connected to the DB-25 connector that is marked 'HOST'. If BASIC11 is 
  125. being used in any other hardware environment, this entry should be set to 
  126. $FFFF.
  127.  
  128. A Configuration Example
  129.  
  130. The following example shows how BASIC11 may be configured for use 
  131. with a typical system.
  132.  
  133. Resource           Location             Use
  134. --------           --------             ---
  135. Volatile RAM       $0000 - $7FFF        Program & Variable storage
  136. EEPROM             $8000 - $BFFF        ESAVE Program & Variable storage
  137.  
  138. In addition, the internal 'clock' must have a resolution of 0.1 seconds.  
  139. Since the memory map between $C000 and $DFFF is currently unused, the 
  140. HC11's internal control and I/O registers will be placed at $C000.
  141.  
  142.           org    $ffc0
  143. RAMStart  fdb    $0100        starting address of system RAM.
  144. ;                             Remember, $00-$FF is reserved!
  145. RAMSize   fdb    $7F00        size of BASIC11 RAM Buffer.
  146. EEStart   fdb    $8000        starting address of program storage EEPROM 
  147. EESize    fdb    $4000        size of the program storage EEPROM
  148. IOBase    fdb    $C000        Base Address of the I/O Registers
  149. TimeVal   fdb    6250         value used for generating 'Time' Interrupt
  150. UserInit  fdb    IODevInit    Used to initialize console/other hardware.
  151. DFLOPADR  fdb    $FFFF        Address of flip-flop used to connect the HC11 SCI
  152. *                             to the host port connector.
  153.  
  154.  
  155. New Commands:
  156.  
  157. The following new commands were added to version 1.55:
  158.  
  159. FREE    FREE
  160.  
  161. The FREE command may be used to Display the amount of 
  162. RAM memory that is currently available for BASIC11 
  163. program statements and variables.  The FREE command 
  164. may only be used while BASIC11 is in the command mode 
  165. (i.e. it may not be used in a program statement).
  166.  
  167. SLEEP    <line number>  SLEEP
  168.  
  169.     700  SLEEP
  170.  
  171. The SLEEP statement allows the MC68HC11 to be put into 
  172. the 'Stop Mode' which is its lowest power consumption 
  173. mode. In the 'Stop Mode', all clocks, including the internal 
  174. oscillator, are stopped and all internal processing is halted. 
  175. Recovery from the SLEEP statement may be accomplished by 
  176. either a processor RESET or an XIRQ interrupt. When an 
  177. XIRQ interrupt is used, BASIC11 will continue execution 
  178. with the next BASIC program statement. When a hardware 
  179. RESET is used to exit the sleep mode, the action taken by 
  180. BASIC11 will depend on two factors. If the 'Auto Start' flag 
  181. has been set with the AUTOST command, the BASIC 
  182. program stored in external EEPROM/EPROM will 
  183. automatically be executed. If the 'Auto Start' flag has not been 
  184. set, BASIC11 will return to the command mode.
  185.  
  186. RTIME    <line number>   RTIME
  187.  
  188.     10  RTIME
  189.  
  190. When assigning a value to the TIME system variable (see page 
  191. 14 of the BASIC11 manual), BASIC11 will update the value 
  192. of the TIME variable asynchronously in relation to interrupts 
  193. generated by output compare one (OC1). The RTIME 
  194. statement will reset the entire system time keeping function. 
  195. The RTIME statement may be used to synchronize the system 
  196. time keeping function to some external event.
  197.  
  198. Note: To maintain accuracy of the system time keeping 
  199. function, the RTIME statement should NOT be used within an 
  200. ONTIME interrupt routine.
  201.  
  202.  
  203.  
  204. IOPKG  --  Micro Dialects, Inc. uASM-HC11 Assembler   Mon, Sep 24, 1990 1:03 PM -- Page 2
  205.  
  206.  
  207.  6982                   *
  208.  6983                   *
  209.  6984 FED2              OUTBYTE          EQU    *
  210.  6985 FED2 7C001E                        INC    PRINTPOS            INCREMENT THE CURRENT PRINT POSITION.
  211.  6986 FED5 37                            PSHB                       SAVE THE B-REG.
  212.  6987 FED6 3C                            PSHX                       SAVE THE X-REG.
  213.  6988 FED7 CE00B4                        LDX    #OUTABLE            POINT TO THE OUTPUT VECTOR TABLE.
  214.  6989 FEDA D637         OUTBYTE1         LDAB   DEVNUM              GET THE CURRENT DEVICE NUMBER.
  215.  6990 FEDC 58                            ASLB                       MULT BY 2.
  216.  6991 FEDD 3A                            ABX                        POINT TO THE ADDRESS OF THE OUTPUT ROUTINE.
  217.  6992 FEDE EE00                          LDX    0,X                 GET THE ADDRESS. HAS THE VECTOR BEEN INITALIZED?
  218.  6993 FEE0 2608                          BNE    OUTBYTE2            YES. GO OUTPUT THE CHARACTER.
  219.  6994 FEE2 7F0037                        CLR    DEVNUM              NO. RESET TO DEVICE #0.
  220.  6995 FEE5 8631                          LDAA   #UNINIERR           GO REPORT AN UNINITALIZED I/O VECTOR ERROR.
  221.  6996 FEE7 7EEAEF                        JMP    RPTRERR
  222.  6997 FEEA AD00         OUTBYTE2         JSR    0,X                 GO OUTPUT THE CHARACTER.
  223.  6998 FEEC 38                            PULX                       RESTORE X.
  224.  6999 FEED 33                            PULB                       RESTORE B.
  225.  7000 FEEE 39                            RTS                        RETURN.
  226.  7001                   *
  227.  7002 FEEF              INBYTE           EQU    *
  228.  7003 FEEF 37                            PSHB                       SAVE THE B-REG.
  229.  7004 FEF0 3C                            PSHX                       SAVE THE X-REG.
  230.  7005 FEF1 CE00A4                        LDX    #INTABLE            POINT TO THE INPUT VECTOR TABLE.
  231.  7006 FEF4 20E4                          BRA    OUTBYTE1            GO USE THE SAME CODE AS OUTBYTE.
  232.  7007                   *
  233.  7008                   *
  234.  7009 0000                               if     *>$FF00
  235.  7011                                    endif
  236.  7012                   *
  237.  7013                   *
  238.  7014 FF00                               ORG    $FF00
  239.  7015                   *
  240.  7016                   *
  241.  7017 FF00 8D0D         ACIAIN           BSR    ACIAINNE            GO GET CHARACTER FROM ACIA, NO ECHO.
  242.  7018                   *                            NOW, FALL THROUGH TO ACIAOUT TO ECHO CHARACTER.
  243.  7019                   *
  244.  7020                   *
  245.  7021 FF02 36           ACIAOUT          PSHA                       SAVE THE CHARACTER TO OUTPUT.
  246.  7022 FF03 B69800       ACIAOUT1         LDAA   ACIAST              GET THE ACIA STATUS.
  247.  7023 FF06 8502                          BITA   #$02                IS THE XMIT DATA REGISTER EMPTY?
  248.  7024 FF08 27F9                          BEQ    ACIAOUT1            NO. WAIT TILL IT IS.
  249.  7025 FF0A 32                            PULA                       YES. GET BYTE TO SEND.
  250.  7026 FF0B B79801                        STAA   ACIADT              SEND IT.
  251.  7027 FF0E 39                            RTS                        RETURN.
  252.  7028                   *
  253.  7029                   *
  254.  7030                   *
  255.  7031                   *
  256.  7032                   *
  257.  7033                   *
  258.  7034 FF0F B69800       ACIAINNE         LDAA   ACIAST              GET THE ACIA STATUS.
  259.  7035 FF12 8501                          BITA   #$01                HAS A CHARACTER BEEN RECIEVED?
  260.  7036 FF14 27F9                          BEQ    ACIAINNE            NO. WAIT TILL WE HAVE ONE.
  261.  7037 FF16 B69801                        LDAA   ACIADT              YES. GET THE CHARACTER.
  262.  7038 FF19 39                            RTS                        RETURN.
  263.  7039                   *
  264.  7040 FF1A              ACIASTAT         EQU    *
  265.  7041 FF1A 36                            PSHA                       SAVE THE A-REG.
  266.  7042 FF1B B69800                        LDAA   ACIAST              GET THE ACIA STATUS.
  267.  7043 FF1E 8501                          BITA   #$01                CHECK FOR A CHARACTER.
  268.  7044 FF20 32                            PULA                       RESTORE A.
  269.  7045 FF21 39                            RTS                        RETURN.
  270.  7046                   *
  271.  7047                   *
  272. IOPKG  --  Micro Dialects, Inc. uASM-HC11 Assembler   Mon, Sep 24, 1990 1:03 PM -- Page 3
  273.  
  274.  
  275.  7048 FF22              SCIIN            EQU    *
  276.  7049 FF22 3C                            PSHX                       Save the index register.
  277.  7050 FF23 DE61                          LDX    IOBaseV
  278.  7051 FF25 A62E         SCIIN1           LDAA   SCSR,X              GET SCI STATUS.
  279.  7052 FF27 8420                          ANDA   #$20                HAS A CHARACTER BEEN RECIEVED?
  280.  7053 FF29 27FA                          BEQ    SCIIN1              NO. WAIT FOR CHARACTER TO BE RECIEVED.
  281.  7054 FF2B A62F                          LDAA   SCDR,X              GET THE CHARACTER.
  282.  7055 FF2D 38                            PULX                       Restore X.
  283.  7056 FF2E 39                            RTS                        RETURN.
  284.  7057                   *
  285.  7058                   *
  286.  7059 FF2F              SCIOUT           EQU    *
  287.  7060 FF2F 3C                            PSHX                       Save the index register.
  288.  7061 FF30 DE61                          LDX    IOBaseV
  289.  7062 FF32 36                            PSHA                       SAVE THE CHARACTER TO SEND.
  290.  7063 FF33 A62E         SCIOUT1          LDAA   SCSR,X              GET THE SCI STATUS.
  291.  7064 FF35 8580                          BITA   #$80                HAS THE LAST CHARACTER BEEN SHIFTED OUT?
  292.  7065 FF37 27FA                          BEQ    SCIOUT1             NO. WAIT TILL IT HAS.
  293.  7066 FF39 32                            PULA                       RESTORE CHARACTER TO SEND.
  294.  7067 FF3A A72F                          STAA   SCDR,X              SEND THE CHARACTER.
  295.  7068 FF3C 38                            PULX                       Restore X.
  296.  7069 FF3D 39                            RTS                        RETURN.
  297.  7070                   *
  298.  7071                   *
  299.  7072 FF3E              SCISTAT          EQU    *
  300.  7073 FF3E 3C                            PSHX                       Save the index register.
  301.  7074 FF3F DE61                          LDX    IOBaseV
  302.  7075 FF41 36                            PSHA                       SAVE THE A-REG.
  303.  7076 FF42 A62E                          LDAA   SCSR,X              GET THE SCI STATUS.
  304.  7077 FF44 8520                          BITA   #$20                CHECK TO SEE IF A CHARACTER HAS BEEN RECIEVED.
  305.  7078 FF46 32                            PULA                       RESTORE STATUS.
  306.  7079 FF47 38                            PULX                       Restore X.
  307.  7080 FF48 39                            RTS                        RETURN W/ STATUS.
  308.  7081                   *
  309.  7082                   *
  310.  7083 FF49              IODevInit:       
  311.  7084 FF49 8D2A                          BSR    InitACIA
  312.  7085 FF4B 8D11                          BSR    InitSCI
  313.  7086 FF4D 867E                          LDAA   #JMPOP
  314.  7087 FF4F 979E                          STAA   CONSTAT             INITIALIZE THE CONSOLE STATUS VECTOR.
  315.  7088 FF51 97A1                          STAA   INCONNE             INITIALIZE THE "INPUT FROM CONSOLE NO ECHO VECT.
  316.  7089 FF53 CCFF1A                        LDD    #ACIASTAT           CONSOLE IS INITIALLY THE ACIA.
  317.  7090 FF56 DD9F                          STD    CONSTAT+1
  318.  7091 FF58 CCFF0F                        LDD    #ACIAINNE           GET BYTE FROM ACIA, DON'T ECHO IT.
  319.  7092 FF5B DDA2                          STD    INCONNE+1
  320.  7093 FF5D 39                            RTS
  321.  7094                   *
  322.  7095                   *
  323.  7096 FF5E              INITSCI          EQU    *
  324.  7097 FF5E 3C                            PSHX                       Save the index register.
  325.  7098 FF5F DE61                          LDX    IOBaseV
  326.  7099 FF61 8630                          LDAA   #$30                SET BAUD RATE TO 9600.
  327.  7100 FF63 A72B                          STAA   BAUD,X
  328.  7101 FF65 6F2C                          CLR    SCCR1,X             SET FOR 8 BIT OPERATION, DISABLE WAKEUP.
  329.  7102 FF67 860C                          LDAA   #$0C                ENABLE THE TRANSMITER & RECEIVER.
  330.  7103 FF69 A72D                          STAA   SCCR2,X
  331.  7104 FF6B 8611                          LDAA   #$11                GET THE XON CHARACTER (CONTROL-Q).
  332.  7105 FF6D 9743                          STAA   XONCH               INITALIZE THE XON REGISTER.
  333.  7106 FF6F 8613                          LDAA   #$13                GET THE XOFF CHARACTER (CONTROL-S).
  334.  7107 FF71 9744                          STAA   XOFFCH              INITALIZE THE XOFF CHARACTER.
  335.  7108 FF73 38                            PULX
  336.  7109 FF74 39                            RTS                        RETURN.
  337.  7110                   *
  338.  7111                   *
  339.  7112 FF75 8613         INITACIA         LDAA   #$13                VALUE TO RESET THE ACIA.
  340. IOPKG  --  Micro Dialects, Inc. uASM-HC11 Assembler   Mon, Sep 24, 1990 1:03 PM -- Page 4
  341.  
  342.  
  343.  7113 FF77 B79800                        STAA   ACIAST              RESET IT.
  344.  7114 FF7A 8656                          LDAA   #$56                SET /64, RTS=HI, 8-DATA/1 STOP
  345.  7115 FF7C B79800                        STAA   ACIAST
  346.  7116 FF7F 39                            RTS                        RETURN.
  347.  7117                   *
  348.  7118                   *
  349.  7119                   *
  350.  7120 FF80              PROUT            EQU    *                   SEND A CHARACTER TO THE PRINTER.
  351.  7121 FF80 8DBC                          BSR    SCISTAT             WAS AN "X-OFF" RECIEVED?
  352.  7122 FF82 270E                          BEQ    PROUT1              NO. GO SEND THE CHARACTER.
  353.  7123 FF84 36                            PSHA                       SAVE THE CHARACTER TO SEND.
  354.  7124 FF85 8D9B                          BSR    SCIIN               YES. GO RESET THE SCI RECEIVER STATUS.
  355.  7125 FF87 9144                          CMPA   XOFFCH              WAS IT AN XOFF?
  356.  7126 FF89 2606                          BNE    PROUT2              NO. SO GO SEND THE CHARACTER.
  357.  7127 FF8B 8D95         PROUT3           BSR    SCIIN               GO WAIT FOR AN "X-ON" CHARACTER.
  358.  7128 FF8D 9143                          CMPA   XONCH               IS IT AN X-ON CHARACTER?
  359.  7129 FF8F 26FA                          BNE    PROUT3              NO. GO WAIT FOR AN X-ON CHARACTER.
  360.  7130 FF91 32           PROUT2           PULA                       GET THE CHARACTER TO SEND.
  361.  7131 FF92 209B         PROUT1           BRA    SCIOUT              SEND THE CHARACTER TO THE PRINTER & RETURN.
  362.  7132                   *
  363.  7133                   *
  364.  7134                                    Include 'VECTORS.Asm'
  365.  7135                                    ttl    Config/Reset/Interrupt Vectors
  366.  
  367.  
  368.  
  369.  
  370.  
  371.  
  372.  
  373.  
  374.  
  375.  
  376.  
  377.  
  378.  
  379.  
  380.  
  381.  
  382.  
  383.  
  384.  
  385.  
  386.  
  387.  
  388.  
  389.  
  390.  
  391.  
  392.  
  393.  
  394.  
  395.  
  396.  
  397.  
  398.  
  399.  
  400.  
  401.  
  402.  
  403.  
  404.  
  405.  
  406.  
  407.  
  408. Config/Reset/Interrupt Vectors  --  Micro Dialects, Inc. uASM-HC11 Assembler   Mon, Sep 24, 1990 1:03 PM -- Page 5
  409.  
  410.  
  411.  7137 0000                               if     *>$ffa0
  412.  7139                                    endif
  413.  7140                   *
  414.  7141                   *
  415.  7142                   *
  416.  7143 FFA0                               org    $ffa0
  417.  7144 FFA0 FF00         IOVects          fdb    ACIAIN
  418.  7145 FFA2 FF22                          fdb    SCIIN
  419.  7146 FFA4 0000                          fdb    0
  420.  7147 FFA6 0000                          fdb    0
  421.  7148 FFA8 0000                          fdb    0
  422.  7149 FFAA 0000                          fdb    0
  423.  7150 FFAC 0000                          fdb    0
  424.  7151 FFAE 0000                          fdb    0
  425.  7152 FFB0 FF02                          fdb    ACIAOUT
  426.  7153 FFB2 FF80                          fdb    PROUT
  427.  7154 FFB4 0000                          fdb    0
  428.  7155 FFB6 0000                          fdb    0
  429.  7156 FFB8 0000                          fdb    0
  430.  7157 FFBA 0000                          fdb    0
  431.  7158 FFBC 0000                          fdb    0
  432.  7159 FFBE 0000                          fdb    0
  433.  7160                   *
  434.  7161                   *
  435.  7162 FFC0                               org    $ffc0
  436.  7163 FFC0 C000         RAMStart         fdb    $c000               starting address of system RAM.
  437.  7164 FFC2 2000         RAMSize          fdb    $2000               size of BASIC11 RAM Buffer.
  438.  7165 FFC4 6000         EEStart          fdb    $6000               starting address of program storage EEPROM 
  439.  7166 FFC6 2000         EESize           fdb    $2000               size of the program storage EEPROM
  440.  7167 FFC8 1000         IOBase           fdb    $1000               Base Address of the I/O Registers
  441.  7168 FFCA F424         TimeVal          fdb    62500               value used for generating 'Time' Interrupt
  442.  7169 FFCC FF49         UserInit         fdb    IODevInit           Used to initialize console/other hardware.
  443.  7170 FFCE 4000         DFLOPADR         fdb    $4000               ; Address of flip-flop used to connect the HC11 SCI
  444.  7171                                                               ; to the host port connector.
  445.  7172                   ;
  446.  7173                   ;
  447.  7174
  448.  7175 FFD6                               ORG    ROMBEG+ROMSIZE-(21*2) START OF VECTOR TABLE.
  449.  7176 FFD6 00C4                          FDB    SCISS               SCI SERIAL SYSTEM
  450.  7177 FFD8 00C7                          FDB    SPITC               SPI TRANSFER COMPLETE
  451.  7178 FFDA 00CA                          FDB    PACCIE              PULSE ACCUMULATOR INPUT EDGE
  452.  7179 FFDC 00CD                          FDB    PACCOVF             PULSE ACCUMULATOR OVERFLOW
  453.  7180 FFDE 00D0                          FDB    TIMEROVF            TIMER OVERFLOW
  454.  7181 FFE0 00D3                          FDB    TOC5                TIMER OUTPUT COMPARE 5
  455.  7182 FFE2 00D6                          FDB    TOC4                TIMER OUTPUT COMPARE 4
  456.  7183 FFE4 00D9                          FDB    TOC3                TIMER OUTPUT COMPARE 3
  457.  7184 FFE6 00DC                          FDB    TOC2                TIMER OUTPUT COMPARE 2
  458.  7185 FFE8 00DF                          FDB    TOC1                TIMER OUTPUT COMPARE 1
  459.  7186 FFEA 00E2                          FDB    TIC3                TIMER INPUT CAPTURE 3
  460.  7187 FFEC 00E5                          FDB    TIC2                TIMER INPUT CAPTURE 2
  461.  7188 FFEE 00E8                          FDB    TIC1                TIMER INPUT CAPTURE 1
  462.  7189 FFF0 00EB                          FDB    REALTIMI            REAL TIME INTERRUPT
  463.  7190 FFF2 00EE                          FDB    IRQI                IRQ INTERRUPT
  464.  7191 FFF4 00F1                          FDB    XIRQ                XIRQ INTERRUPT
  465.  7192 FFF6 00F4                          FDB    SWII                SOFTWARE INTERRUPT
  466.  7193 FFF8 00F7                          FDB    ILLOP               ILLEGAL OPCODE TRAP
  467.  7194 FFFA 00FA                          FDB    COP                 WATCH DOG FAIL
  468.  7195 FFFC 00FD                          FDB    CMF                 CLOCK MONITOR FAIL
  469.  7196 FFFE ED77                          FDB    POWERUP             RESET
  470.  7197                   *
  471.  7198                   *
  472.  7199                   *
  473.